mirror of
https://github.com/apache/nuttx.git
synced 2026-08-14 08:53:15 +00:00
87260499e1
Some checks are pending
MemBrowse Memory Report / changes-filter (push) Waiting to run
MemBrowse Memory Report / load-targets (push) Waiting to run
MemBrowse Memory Report / identical (push) Blocked by required conditions
MemBrowse Memory Report / analyze (push) Blocked by required conditions
This change fixes NuttX’s CMake support when NuttX is embedded in another project via add_subdirectory(). CMake’s CMAKE_SOURCE_DIR and CMAKE_BINARY_DIR refer to the outermost project, causing NuttX to access its .config, generated files, host tools, and build artifacts in the parent project’s directories. The fix introduces NUTTX_DIR and NUTTX_BINARY_DIR, based on CMAKE_CURRENT_SOURCE_DIR and CMAKE_CURRENT_BINARY_DIR, and consistently uses them for NuttX self-references while preserving existing standalone builds. It fixes the Kconfig initialization failure reported in #19697 and allows an embedded sim:nsh build to configure, build, and boot successfully. The change affects only the CMake build system (not Make or Kconfig defaults), requires the corresponding nuttx-apps change, and does not extend add_subdirectory() support to cross-compiled non-sim boards due to CMake’s toolchain-file limitation. Fixes #19697. Assisted-by: Claude:claude-sonnet-5 Signed-off-by: Alan Carvalho de Assis <acassis@gmail.com>
120 lines
4.6 KiB
CMake
120 lines
4.6 KiB
CMake
# ##############################################################################
|
|
# cmake/nuttx_sethost.cmake
|
|
#
|
|
# SPDX-License-Identifier: Apache-2.0
|
|
#
|
|
# Licensed to the Apache Software Foundation (ASF) under one or more contributor
|
|
# license agreements. See the NOTICE file distributed with this work for
|
|
# additional information regarding copyright ownership. The ASF licenses this
|
|
# file to you under the Apache License, Version 2.0 (the "License"); you may not
|
|
# use this file except in compliance with the License. You may obtain a copy of
|
|
# the License at
|
|
#
|
|
# http://www.apache.org/licenses/LICENSE-2.0
|
|
#
|
|
# Unless required by applicable law or agreed to in writing, software
|
|
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
|
|
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
|
|
# License for the specific language governing permissions and limitations under
|
|
# the License.
|
|
#
|
|
# ##############################################################################
|
|
|
|
include(nuttx_kconfig)
|
|
|
|
function(nuttx_sethost)
|
|
set(config_file ${NUTTX_BINARY_DIR}/.config)
|
|
cmake_parse_arguments(SETHOST "" "CONFIG_FILE" "" ${ARGN})
|
|
|
|
if(SETHOST_UNPARSED_ARGUMENTS)
|
|
message(
|
|
FATAL_ERROR
|
|
"nuttx_sethost: unknown arguments: ${SETHOST_UNPARSED_ARGUMENTS}")
|
|
endif()
|
|
|
|
if(SETHOST_CONFIG_FILE)
|
|
set(config_file ${SETHOST_CONFIG_FILE})
|
|
endif()
|
|
|
|
if(CMAKE_HOST_WIN32)
|
|
# https://learn.microsoft.com/en-us/windows/win32/winprog64/wow64-implementation-details
|
|
if(DEFINED ENV{PROCESSOR_ARCHITEW6432})
|
|
set(CMAKE_HOST_SYSTEM_PROCESSOR "$ENV{PROCESSOR_ARCHITEW6432}")
|
|
message(
|
|
STATUS " ENV{PROCESSOR_ARCHITEW6432} = $ENV{PROCESSOR_ARCHITEW6432}")
|
|
else()
|
|
set(CMAKE_HOST_SYSTEM_PROCESSOR "$ENV{PROCESSOR_ARCHITECTURE}")
|
|
message(
|
|
STATUS " ENV{PROCESSOR_ARCHITECTURE} = $ENV{PROCESSOR_ARCHITECTURE}")
|
|
endif()
|
|
else()
|
|
execute_process(
|
|
COMMAND uname -m
|
|
COMMAND tr -d '\n'
|
|
OUTPUT_VARIABLE ARCHITECTURE)
|
|
endif()
|
|
|
|
set(NUTTX_SYSTEM_SETHOST)
|
|
|
|
if(CMAKE_HOST_SYSTEM_NAME MATCHES "Linux|Darwin|FreeBSD")
|
|
if(CMAKE_HOST_SYSTEM_NAME MATCHES "Linux")
|
|
message(" Select HOST_LINUX=y")
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "HOST_LINUX=y")
|
|
elseif(CMAKE_HOST_SYSTEM_NAME MATCHES "Darwin")
|
|
message(" Select HOST_MACOS=y")
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "HOST_MACOS=y")
|
|
elseif(CMAKE_HOST_SYSTEM_NAME MATCHES "FreeBSD")
|
|
message(" Select HOST_BSD=y")
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "HOST_BSD=y")
|
|
endif()
|
|
elseif(CMAKE_HOST_SYSTEM_NAME MATCHES "MSYS|CYGWIN|Windows")
|
|
message(" Select HOST_WINDOWS=y")
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "HOST_WINDOWS=y")
|
|
if(CMAKE_HOST_SYSTEM_NAME MATCHES "CYGWIN")
|
|
message(" Select WINDOWS_CYGWIN=y")
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "WINDOWS_CYGWIN=y")
|
|
elseif(CMAKE_HOST_SYSTEM_NAME MATCHES "MSYS")
|
|
message(" Select WINDOWS_MSYS=y")
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "WINDOWS_MSYS=y")
|
|
elseif(CMAKE_HOST_SYSTEM_NAME MATCHES "Windows")
|
|
message(" Select WINDOWS_NATIVE=y")
|
|
if(NOT MSVC)
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "EXPERIMENTAL=y")
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "WINDOWS_NATIVE=y")
|
|
else()
|
|
message(" MSVC toolchain")
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "WINDOWS_NATIVE=y")
|
|
endif()
|
|
endif()
|
|
else()
|
|
message(" Select HOST_OTHER=y")
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "HOST_OTHER=y")
|
|
# nuttx_setconfig(OTHER_OS=y)
|
|
endif()
|
|
|
|
if("${NUTTX_BOARD}" STREQUAL "sim")
|
|
if(ARCHITECTURE STREQUAL "x86_64")
|
|
message(" Select HOST_X86_64=y")
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "HOST_X86_64=y")
|
|
if(CMAKE_HOST_SYSTEM_NAME MATCHES "Linux|Darwin|FreeBSD")
|
|
# Enable the System V ABI
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "SIM_X8664_SYSTEMV=y")
|
|
elseif(CMAKE_HOST_SYSTEM_NAME MATCHES "MSYS|CYGWIN|Windows")
|
|
# Enable Microsoft ABI and the System V ABI
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "SIM_X8664_SYSTEMV=y")
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "SIM_X8664_MICROSOFT=y")
|
|
endif()
|
|
elseif(ARCHITECTURE STREQUAL "x86")
|
|
message(" Select HOST_X86=y")
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "HOST_X86=y")
|
|
elseif(ARCHITECTURE STREQUAL "arm")
|
|
message(" Select HOST_ARM=y")
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "HOST_ARM=y")
|
|
elseif(ARCHITECTURE MATCHES "^(arm64|aarch64)$")
|
|
message(" Select HOST_ARM64=y")
|
|
list(APPEND NUTTX_SYSTEM_SETHOST "HOST_ARM64=y")
|
|
endif()
|
|
endif()
|
|
# message(" nuttx_setconfig: ${NUTTX_SYSTEM_SETHOST}")
|
|
nuttx_setconfig(CONFIG_FILE ${config_file} SETTINGS ${NUTTX_SYSTEM_SETHOST})
|
|
endfunction()
|