mirror of
https://github.com/apache/nuttx.git
synced 2026-08-14 08:53:15 +00:00
87260499e1
Some checks are pending
MemBrowse Memory Report / changes-filter (push) Waiting to run
MemBrowse Memory Report / load-targets (push) Waiting to run
MemBrowse Memory Report / identical (push) Blocked by required conditions
MemBrowse Memory Report / analyze (push) Blocked by required conditions
This change fixes NuttX’s CMake support when NuttX is embedded in another project via add_subdirectory(). CMake’s CMAKE_SOURCE_DIR and CMAKE_BINARY_DIR refer to the outermost project, causing NuttX to access its .config, generated files, host tools, and build artifacts in the parent project’s directories. The fix introduces NUTTX_DIR and NUTTX_BINARY_DIR, based on CMAKE_CURRENT_SOURCE_DIR and CMAKE_CURRENT_BINARY_DIR, and consistently uses them for NuttX self-references while preserving existing standalone builds. It fixes the Kconfig initialization failure reported in #19697 and allows an embedded sim:nsh build to configure, build, and boot successfully. The change affects only the CMake build system (not Make or Kconfig defaults), requires the corresponding nuttx-apps change, and does not extend add_subdirectory() support to cross-compiled non-sim boards due to CMake’s toolchain-file limitation. Fixes #19697. Assisted-by: Claude:claude-sonnet-5 Signed-off-by: Alan Carvalho de Assis <acassis@gmail.com>
129 lines
5.4 KiB
CMake
129 lines
5.4 KiB
CMake
# ##############################################################################
|
|
# cmake/menuconfig.cmake
|
|
#
|
|
# SPDX-License-Identifier: Apache-2.0
|
|
#
|
|
# Licensed to the Apache Software Foundation (ASF) under one or more contributor
|
|
# license agreements. See the NOTICE file distributed with this work for
|
|
# additional information regarding copyright ownership. The ASF licenses this
|
|
# file to you under the Apache License, Version 2.0 (the "License"); you may not
|
|
# use this file except in compliance with the License. You may obtain a copy of
|
|
# the License at
|
|
#
|
|
# http://www.apache.org/licenses/LICENSE-2.0
|
|
#
|
|
# Unless required by applicable law or agreed to in writing, software
|
|
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
|
|
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
|
|
# License for the specific language governing permissions and limitations under
|
|
# the License.
|
|
#
|
|
# ##############################################################################
|
|
|
|
# menuconfig target this triggers a reconfiguration (TODO: do only if config
|
|
# changes)
|
|
|
|
set(KCONFIG_ENV
|
|
"KCONFIG_CONFIG=${NUTTX_BINARY_DIR}/.config" "EXTERNALDIR=dummy"
|
|
"APPSDIR=${NUTTX_APPS_DIR}" "DRIVERS_PLATFORM_DIR=dummy"
|
|
"APPSBINDIR=${NUTTX_APPS_BINDIR}" "BINDIR=${NUTTX_BINARY_DIR}")
|
|
|
|
# Use qconfig instead of menuconfig since PowerShell not support curses
|
|
# redirection
|
|
|
|
if(WIN32)
|
|
set(MENUCONFIG guiconfig)
|
|
else()
|
|
set(MENUCONFIG menuconfig)
|
|
endif()
|
|
|
|
add_custom_target(
|
|
menuconfig
|
|
COMMAND ${CMAKE_COMMAND} -E env ${KCONFIG_ENV} ${MENUCONFIG}
|
|
COMMAND ${CMAKE_COMMAND} -E remove -f
|
|
${NUTTX_BINARY_DIR}/include/nuttx/config.h # invalidate existing
|
|
# config
|
|
COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_PARENT_LIST_FILE}
|
|
WORKING_DIRECTORY ${NUTTX_DIR}
|
|
USES_TERMINAL)
|
|
|
|
# qconfig target
|
|
|
|
add_custom_target(
|
|
qconfig
|
|
COMMAND ${CMAKE_COMMAND} -E env ${KCONFIG_ENV} guiconfig
|
|
COMMAND ${CMAKE_COMMAND} -E remove -f
|
|
${NUTTX_BINARY_DIR}/include/nuttx/config.h # invalidate existing
|
|
# config
|
|
COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_PARENT_LIST_FILE}
|
|
WORKING_DIRECTORY ${NUTTX_DIR}
|
|
USES_TERMINAL)
|
|
|
|
# Refresh ${NUTTX_BINARY_DIR}/.config in place (set defaults, satisfy deps),
|
|
# like "make olddefconfig". Use after hand-editing .config; does not copy from
|
|
# board defconfig (see resetconfig for that).
|
|
add_custom_target(
|
|
olddefconfig
|
|
COMMAND ${CMAKE_COMMAND} -E env ${KCONFIG_ENV} olddefconfig
|
|
COMMAND ${CMAKE_COMMAND} -E remove -f
|
|
${NUTTX_BINARY_DIR}/include/nuttx/config.h
|
|
COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_PARENT_LIST_FILE}
|
|
WORKING_DIRECTORY ${NUTTX_DIR})
|
|
|
|
# utility target to restore .config from board's defconfig
|
|
add_custom_target(
|
|
resetconfig
|
|
COMMAND ${CMAKE_COMMAND} -E copy ${NUTTX_DEFCONFIG}
|
|
${NUTTX_BINARY_DIR}/.config
|
|
COMMAND ${CMAKE_COMMAND} -E env ${KCONFIG_ENV} olddefconfig
|
|
COMMAND ${CMAKE_COMMAND} -E copy ${NUTTX_BINARY_DIR}/.config
|
|
${NUTTX_BINARY_DIR}/.config.orig
|
|
COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_PARENT_LIST_FILE}
|
|
WORKING_DIRECTORY ${NUTTX_DIR})
|
|
|
|
# utility target to remove .config (and related) so next configure regenerates
|
|
# from the current BOARD_CONFIG defconfig. Use when switching defconfigs after
|
|
# "clean" so that the next "cmake -B build -DBOARD_CONFIG=board:newconfig"
|
|
# recreates .config from the new defconfig.
|
|
add_custom_target(
|
|
distcleanconfig
|
|
COMMAND
|
|
${CMAKE_COMMAND} -E remove -f ${NUTTX_BINARY_DIR}/.config
|
|
${NUTTX_BINARY_DIR}/.config.orig ${NUTTX_BINARY_DIR}/.config.prev
|
|
${NUTTX_BINARY_DIR}/include/nuttx/config.h
|
|
WORKING_DIRECTORY ${NUTTX_DIR})
|
|
|
|
# utility target to refresh .config from board's defconfig for GITHUB
|
|
add_custom_target(
|
|
refreshsilent
|
|
COMMAND ${CMAKE_COMMAND} -E remove -f ${NUTTX_BINARY_DIR}/SAVEconfig
|
|
COMMAND ${CMAKE_COMMAND} -E copy ${NUTTX_BINARY_DIR}/.config
|
|
${NUTTX_BINARY_DIR}/SAVEconfig
|
|
COMMAND ${CMAKE_COMMAND} -E remove -f ${NUTTX_BINARY_DIR}/.config
|
|
COMMAND ${CMAKE_COMMAND} -E copy ${NUTTX_DEFCONFIG}
|
|
${NUTTX_BINARY_DIR}/.config
|
|
COMMAND ${CMAKE_COMMAND} -E env ${KCONFIG_ENV} olddefconfig
|
|
COMMAND ${CMAKE_COMMAND} -E env ${KCONFIG_ENV} savedefconfig --out
|
|
${NUTTX_BINARY_DIR}/defconfig.tmp
|
|
COMMAND ${CMAKE_COMMAND} -P ${NUTTX_DIR}/cmake/savedefconfig.cmake
|
|
${NUTTX_BINARY_DIR}/.config ${NUTTX_BINARY_DIR}/defconfig.tmp
|
|
COMMAND ${CMAKE_COMMAND} -E copy_if_different ${NUTTX_BINARY_DIR}/defconfig
|
|
${NUTTX_DEFCONFIG}
|
|
WORKING_DIRECTORY ${NUTTX_DIR})
|
|
|
|
# utility target to replace defconfig to board's defconfig
|
|
add_custom_target(
|
|
savedefconfig
|
|
COMMAND ${CMAKE_COMMAND} -E env ${KCONFIG_ENV} savedefconfig --out
|
|
${NUTTX_BINARY_DIR}/defconfig.tmp
|
|
COMMAND ${CMAKE_COMMAND} -P ${NUTTX_DIR}/cmake/savedefconfig.cmake
|
|
${NUTTX_BINARY_DIR}/.config ${NUTTX_BINARY_DIR}/defconfig.tmp
|
|
COMMAND
|
|
${Python3_EXECUTABLE} ${NUTTX_DIR}/tools/process_config.py postprocess
|
|
${NUTTX_BINARY_DIR}/config_tree.json ${NUTTX_BINARY_DIR}/defconfig.orig
|
|
${NUTTX_BINARY_DIR}/defconfig ${NUTTX_BINARY_DIR}/defconfig.post
|
|
COMMAND ${CMAKE_COMMAND} -E copy_if_different
|
|
${NUTTX_BINARY_DIR}/defconfig.post ${NUTTX_DEFCONFIG}
|
|
COMMAND ${CMAKE_COMMAND} -E copy_if_different
|
|
${NUTTX_BINARY_DIR}/defconfig.post ${NUTTX_ORIG_DEFCONFIG}
|
|
WORKING_DIRECTORY ${NUTTX_DIR})
|