mirror of
https://github.com/apache/nuttx.git
synced 2026-10-03 04:07:55 +00:00
87260499e1
Some checks are pending
MemBrowse Memory Report / changes-filter (push) Waiting to run
MemBrowse Memory Report / load-targets (push) Waiting to run
MemBrowse Memory Report / identical (push) Blocked by required conditions
MemBrowse Memory Report / analyze (push) Blocked by required conditions
This change fixes NuttX’s CMake support when NuttX is embedded in another project via add_subdirectory(). CMake’s CMAKE_SOURCE_DIR and CMAKE_BINARY_DIR refer to the outermost project, causing NuttX to access its .config, generated files, host tools, and build artifacts in the parent project’s directories. The fix introduces NUTTX_DIR and NUTTX_BINARY_DIR, based on CMAKE_CURRENT_SOURCE_DIR and CMAKE_CURRENT_BINARY_DIR, and consistently uses them for NuttX self-references while preserving existing standalone builds. It fixes the Kconfig initialization failure reported in #19697 and allows an embedded sim:nsh build to configure, build, and boot successfully. The change affects only the CMake build system (not Make or Kconfig defaults), requires the corresponding nuttx-apps change, and does not extend add_subdirectory() support to cross-compiled non-sim boards due to CMake’s toolchain-file limitation. Fixes #19697. Assisted-by: Claude:claude-sonnet-5 Signed-off-by: Alan Carvalho de Assis <acassis@gmail.com>
100 lines
3.1 KiB
CMake
100 lines
3.1 KiB
CMake
# ##############################################################################
|
|
# drivers/segger/CMakeLists.txt
|
|
#
|
|
# SPDX-License-Identifier: Apache-2.0
|
|
#
|
|
# Licensed to the Apache Software Foundation (ASF) under one or more contributor
|
|
# license agreements. See the NOTICE file distributed with this work for
|
|
# additional information regarding copyright ownership. The ASF licenses this
|
|
# file to you under the Apache License, Version 2.0 (the "License"); you may not
|
|
# use this file except in compliance with the License. You may obtain a copy of
|
|
# the License at
|
|
#
|
|
# http://www.apache.org/licenses/LICENSE-2.0
|
|
#
|
|
# Unless required by applicable law or agreed to in writing, software
|
|
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
|
|
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
|
|
# License for the specific language governing permissions and limitations under
|
|
# the License.
|
|
#
|
|
# ##############################################################################
|
|
|
|
if(CONFIG_SEGGER_RTT OR CONFIG_SEGGER_SYSVIEW)
|
|
if(NOT EXISTS ${CMAKE_CURRENT_LIST_DIR}/SystemView)
|
|
|
|
FetchContent_Declare(
|
|
systemview
|
|
DOWNLOAD_NAME "SystemView.zip"
|
|
DOWNLOAD_DIR ${CMAKE_CURRENT_LIST_DIR}
|
|
URL "https://github.com/NuttX/nuttx/releases/download/systemview/SystemView_Src_V${CONFIG_SEGGER_SYSVIEW_TARGET_SOURCE}.zip"
|
|
SOURCE_DIR
|
|
${CMAKE_CURRENT_LIST_DIR}/SystemView
|
|
BINARY_DIR
|
|
${NUTTX_BINARY_DIR}/SystemView
|
|
DOWNLOAD_NO_PROGRESS true
|
|
TIMEOUT 30)
|
|
|
|
FetchContent_GetProperties(systemview)
|
|
|
|
if(NOT systemview_POPULATED)
|
|
FetchContent_Populate(systemview)
|
|
endif()
|
|
endif()
|
|
endif()
|
|
|
|
if(CONFIG_SEGGER_RTT)
|
|
nuttx_add_kernel_library(RTT)
|
|
|
|
target_sources(RTT PRIVATE segger.c)
|
|
|
|
set(RTT_SRCS SystemView/SEGGER/SEGGER_RTT.c)
|
|
|
|
if(CONFIG_SEGGER_RTT_SECTION)
|
|
target_compile_options(
|
|
RTT PRIVATE -DSEGGER_RTT_SECTION=${CONFIG_SEGGER_RTT_SECTION})
|
|
endif()
|
|
|
|
if(CONFIG_SEGGER_RTT_BUFFER_SECTION)
|
|
target_compile_options(
|
|
RTT
|
|
PRIVATE -DSEGGER_RTT_BUFFER_SECTION=${CONFIG_SEGGER_RTT_BUFFER_SECTION})
|
|
endif()
|
|
|
|
if(CONFIG_ARCH_ARMV7M)
|
|
list(APPEND RTT_SRCS SystemView/SEGGER/SEGGER_RTT_ASM_ARMv7M.S)
|
|
endif()
|
|
|
|
if(CONFIG_STREAM_RTT)
|
|
list(APPEND RTT_SRCS stream_rtt.c)
|
|
endif()
|
|
|
|
if(CONFIG_SYSLOG_RTT)
|
|
list(APPEND RTT_SRCS syslog_rtt.c)
|
|
endif()
|
|
|
|
if(CONFIG_NOTE_RTT)
|
|
list(APPEND RTT_SRCS note_rtt.c)
|
|
endif()
|
|
|
|
if(CONFIG_SERIAL_RTT)
|
|
list(APPEND RTT_SRCS serial_rtt.c)
|
|
endif()
|
|
|
|
target_compile_options(RTT PRIVATE -Wno-shadow -Wno-pointer-to-int-cast)
|
|
target_sources(RTT PRIVATE ${RTT_SRCS})
|
|
target_include_directories(RTT PRIVATE config SystemView/SEGGER)
|
|
endif()
|
|
|
|
if(CONFIG_SEGGER_SYSVIEW)
|
|
nuttx_add_kernel_library(SystemView)
|
|
|
|
target_compile_options(SystemView PRIVATE -Wno-shadow
|
|
-Wno-pointer-to-int-cast)
|
|
target_sources(SystemView PRIVATE note_sysview.c
|
|
SystemView/SEGGER/SEGGER_SYSVIEW.c)
|
|
|
|
target_include_directories(SystemView PRIVATE ${NUTTX_DIR}/sched config
|
|
RTT/RTT SystemView/SEGGER)
|
|
|
|
endif()
|